[Mimedefang] Enumerating MX host IP's

[Kenneth Porter]

--On Thursday, March 25, 2004 3:41 PM -0800 Kenneth Porter 
<shiva at sewingwitch.com> wrote:

> Does anyone have code that will enumerate the IP's for all MX hosts for a
> domain?

After a bit of googling for examples I turned this out:

use Net::DNS;

# GetHostAddresses(resolver,hostname)
# returns list of IP addresses for hostname

sub GetHostAddresses ($$) {
        my ($resolver,$hostname) = @_;
        my @addresses;
        my $received = $resolver->search($hostname);
        foreach my $rr ($received->answer) {
                next unless $rr->type eq "A";
                push(@addresses, $rr->address);
        }
        return @addresses;
}

# GetDomainMXAddresses(resolver,domain)
# returns array of IP addresses for domain's MX list
# if no MX records, returns array of IP addresses for this hostname

sub GetDomainMXAddresses ($$) {
        my ($resolver,$domain) = @_;
        my  @mxlist = mx($resolver, $domain);
        my @mxaddresses;
        if (@mxlist) {
                push(@mxaddresses, map { GetHostAddresses($resolver, 
$_->exchange); } @mxlist);
        } else { # check for an A record for the domain...
                push(@mxaddresses, GetHostAddresses($resolver, $domain));
        }
        return @mxaddresses;
}

# MTA_is_domain_MX(domain,address)
# returns TRUE if address is a MX for domain

sub MTA_is_domain_MX ($$) {
        my ($domain,$address) = @_;
        return grep { /^$address$/ } 
GetDomainMXAddresses(Net::DNS::Resolver->new, $domain);
}